1/* setjmp for ARM.
2   Copyright (C) 1997-2021 Free Software Foundation, Inc.
3   This file is part of the GNU C Library.
4
5   The GNU C Library is free software; you can redistribute it and/or
6   modify it under the terms of the GNU Lesser General Public
7   License as published by the Free Software Foundation; either
8   version 2.1 of the License, or (at your option) any later version.
9
10   The GNU C Library is distributed in the hope that it will be useful,
11   but WITHOUT ANY WARRANTY; without even the implied warranty of
12   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13   Lesser General Public License for more details.
14
15   You should have received a copy of the GNU Lesser General Public
16   License along with the GNU C Library.  If not, see
17   <https://www.gnu.org/licenses/>.  */
18
19#include <sysdep.h>
20#include <stap-probe.h>
21#include <bits/setjmp.h>
22#include <rtld-global-offsets.h>
23#include <arm-features.h>
24
25ENTRY (__sigsetjmp)
26#ifdef PTR_MANGLE
27	PTR_MANGLE_LOAD (a3, ip)
28#endif
29	mov	ip, r0
30
31	/* setjmp probe expects sigsetjmp first argument (4@r0), second
32	   argument (-4@r1), and target address (4@r14), respectively.  */
33	LIBC_PROBE (setjmp, 3, 4@r0, -4@r1, 4@r14)
34
35	/* Save sp and lr */
36#ifdef PTR_MANGLE
37	mov	a4, sp
38	PTR_MANGLE2 (a4, a4, a3)
39	str	a4, [ip], #4
40	PTR_MANGLE2 (a4, lr, a3)
41	str	a4, [ip], #4
42#else
43	str	sp, [ip], #4
44	str	lr, [ip], #4
45#endif
46	/* Save registers */
47	stmia	ip!, JMP_BUF_REGLIST
48
49#if !defined ARM_ASSUME_NO_IWMMXT || defined __SOFTFP__
50# define NEED_HWCAP 1
51#endif
52
53#ifdef NEED_HWCAP
54	/* Check if we have a VFP unit.  */
55# if IS_IN (rtld)
56	LDST_PCREL (ldr, a3, a4, \
57		    C_SYMBOL_NAME(_rtld_local_ro) \
58		    + RTLD_GLOBAL_RO_DL_HWCAP_OFFSET)
59# else
60#  ifdef SHARED
61	LDR_GLOBAL (a3, a4, C_SYMBOL_NAME(_rtld_global_ro), \
62		    RTLD_GLOBAL_RO_DL_HWCAP_OFFSET)
63#  else
64	LDR_GLOBAL (a3, a4, C_SYMBOL_NAME(_dl_hwcap), 0)
65#  endif
66# endif
67#endif
68
69#ifdef __SOFTFP__
70	tst	a3, #HWCAP_ARM_VFP
71	beq	.Lno_vfp
72#endif
73
74	/* Store the VFP registers.
75	   Don't use VFP instructions directly because this code
76	   is used in non-VFP multilibs.  */
77	/* Following instruction is vstmia ip!, {d8-d15}.  */
78	stc	p11, cr8, [ip], #64
79.Lno_vfp:
80
81#ifndef ARM_ASSUME_NO_IWMMXT
82	tst	a3, #HWCAP_ARM_IWMMXT
83	beq	.Lno_iwmmxt
84
85	/* Save the call-preserved iWMMXt registers.  */
86	/* Following instructions are wstrd wr10, [ip], #8 (etc.)  */
87	stcl	p1, cr10, [r12], #8
88	stcl	p1, cr11, [r12], #8
89	stcl	p1, cr12, [r12], #8
90	stcl	p1, cr13, [r12], #8
91	stcl	p1, cr14, [r12], #8
92	stcl	p1, cr15, [r12], #8
93.Lno_iwmmxt:
94#endif
95
96	/* Make a tail call to __sigjmp_save; it takes the same args.  */
97	B	PLTJMP(C_SYMBOL_NAME(__sigjmp_save))
98
99END (__sigsetjmp)
100
101hidden_def (__sigsetjmp)
102